Binaryworld - GetSystemIcon - Get a Windows standard icon as a StdPicture object ... [ VB -> Graphics ]

Private Declare Function LoadStandardIcon Lib "user32" Alias "LoadIconA" (ByVal _
  hInstance As Long, ByVal lIconID As Long) As Long

Enum SystemIconConstants
  IDI_Application = 32512
  IDI_Hand = 32513
  IDI_Question = 32514
  IDI_Exclamation = 32515
  IDI_Asterisk = 32516
  IDI_Windows = 32517
End Enum

Private Type PICTDESC
cbSize As Long
pictType As Long
hIcon As Long
hPal As Long
End Type

Private Declare Function OleCreatePictureIndirect Lib "olepro32.dll" _
(lpPictDesc As PICTDESC, riid As Any, ByVal fOwn As Long, _
ipic As IPicture) As Long

' Convert an icon handle to a Picture object

Function IconToPicture(ByVal hIcon As Long) As Picture
Dim pic As PICTDESC
Dim guid(0 To 3) As Long

' initialize the PictDesc structure
pic.cbSize = Len(pic)
pic.pictType = vbPicTypeIcon
pic.hIcon = hIcon
' this is the IPicture GUID {7BF80980-BF32-101A-8BBB-00AA00300CAB}
' we use an array of Long to initialize it faster
guid(0) = &H7BF80980
guid(1) = &H101ABF32
guid(2) = &HAA00BB8B
guid(3) = &HAB0C3000
' create the picture,
' return an object reference right into the function result
OleCreatePictureIndirect pic, guid(0), True, IconToPicture
End Function
' returns a Windows standard icon
' (e.g. the icons used in the Message Boxes)
'

Function GetSystemIcon(ByVal ID As SystemIconConstants) As StdPicture
'get the standard icon's handle by calling LoadStandardIcon and then
'convert it to a StdPicture object
Set GetSystemIcon = IconToPicture(LoadStandardIcon(0, ID))
End Function