Binaryworld - CheckSpelling - Using the Word's check-spelling engine ... [ VB -> Exteral Libs ]

' Do the check spelling on the input text
' Returns the input text with the corrections applied from the Word's check-
' spelling dialog
' Note: it requires a reference to the MS Word 9.0 library
'
' Example:
' MsgBox (CheckSpelling("This sentence iss far from being correcta"))

Function CheckSpelling(ByVal strString As String) As String
  Dim objWord As Word.Application
  Dim objDoc As Word.Document

  ' use the hourglass mouse cursor
  Dim oldMousePointer As Variant
  oldMousePointer = Screen.MousePointer
  Screen.MousePointer = vbHourglass

  Set objWord = New Word.Application

  With objWord
    .Visible = False
    ' create a new document, and "paste" the input text
    Set objDoc = .Documents.Add
    .Selection.Text = strString
    ' run the check-spelling
    .Dialogs(wdDialogToolsSpellingAndGrammar).Show
    strString = .Selection.Text
    ' close the document
    objDoc.Close wdDonotSaveChanges
    Set objDoc = Nothing
    ' close the Word instance
    .Quit wdDonotSaveChanges
  End With

  Set objWord = Nothing
  ' restore the original couse cursor
  Screen.MousePointer = oldMousePointer

  CheckSpelling = strString
End Function