Binaryworld - JoinQuoted - A Join variant that encloses string values in quotes ... [ VB -> String ]

' Join variant that works with arrays of any type
' and that encloses string values between quotes
'
' ARR is the array whose element must be joined
' SEPARATOR is the separator char (default is comma)
' QUOTED is the character used to quote string values
'   use a two-char string (eg "{}") if the openining
'   and closing quote chars are different
'   use a null string to suppress quoting feature

Function JoinQuoted(arr As Variant, Optional ByVal Separator As String = ",", _
  Optional ByVal Quotes As String = """") As String
  Dim res As String
  Dim index As Long

  For index = LBound(arr) To UBound(arr)
    If VarType(arr(index)) <> vbString Then
      res = res & Separator & arr(index)
    Else
      ' the following code works correctly if
      ' LEN(Quotes) is 0,1,2
      res = res & Separator & Left$(Quotes, _
        1) & arr(index) & Right$(Quotes, 1)
    End If
  Next

  ' drop the first separator
  JoinQuoted = Mid$(res, Len(Separator) + 1)

End Function