Binaryworld - RotateRightI - Rotate an Integer to the right ... [ VB -> Math ]

' Rotate an Integer to the right the specified number of times
'
' NOTE: requires Power2()

Function RotateRightI(ByVal value As Integer, ByVal times As Long) As Integer
  Dim i As Long, signBits As Integer

  ' no need to rotate more times than required
  times = times Mod 16
  ' return the number if it's a multiple of 16
  If times = 0 Then RotateRightI = value: Exit Function

  For i = 1 To times
    ' remember the sign bit and bit 0
    signBits = value And &H8001
    ' clear those bits and shift to the right by one position
    value = (value And &H7FFE) \ 2
    ' if the number was negative, then re-insert the bit
    ' if bit 0 was set, then set the sign bit
    value = value Or ((signBits < 0) And &H4000) Or (CBool(signBits And 1) _
      And &H8000)
  Next
  RotateRightI = value
End Function

' Raise 2 to a power
' the exponent must be in the range [0,31]

Function Power2(ByVal exponent As Long) As Long
  Static res(0 To 31) As Long
  Dim i As Long

  ' rule out errors
  If exponent < 0 Or exponent > 31 Then Err.Raise 5

  ' initialize the array at the first call
  If res(0) = 0 Then
    res(0) = 1
    For i = 1 To 30
      res(i) = res(i - 1) * 2
    Next
    ' this is a special case
    res(31) = &H80000000
  End If

  ' return the result
  Power2 = res(exponent)

End Function