Binaryworld - BinToDec - Convert from binary to decimal ... [ VB -> Math ]

' convert from binary to decimal
'

Function BinToDec(value As String) As Long
  Dim result As Long, i As Integer, exponent As Integer
  For i = Len(value) To 1 Step -1
    Select Case Asc(Mid$(value, i, 1))
      Case 48   ' "0", do nothing
      Case 49   ' "1", add the corresponding power of 2
        result = result Or Power2(exponent)
      Case Else
        Err.Raise 5   ' Invalid procedure call or argument
    End Select
    exponent = exponent + 1
  Next
  BinToDec = result
End Function

' Raise 2 to a power
' the exponent must be in the range [0,31]

Function Power2(ByVal exponent As Long) As Long
  Static res(0 To 31) As Long
  Dim i As Long

  ' rule out errors
  If exponent < 0 Or exponent > 31 Then Err.Raise 5

  ' initialize the array at the first call
  If res(0) = 0 Then
    res(0) = 1
    For i = 1 To 30
      res(i) = res(i - 1) * 2
    Next
    ' this is a special case
    res(31) = &H80000000
  End If

  ' return the result
  Power2 = res(exponent)

End Function