Binaryworld - Tip: How to display all environment variables ... [ VB -> Windows ]

Private Declare Function GetEnvironmentStrings Lib "kernel32" Alias "GetEnvironmentStringsA" () As Long
Private Declare Function FreeEnvironmentStrings Lib "kernel32" Alias "FreeEnvironmentStringsA" (ByVal lpsz As String) As Long
Private Declare Function lstrlen Lib "kernel32" Alias "lstrlenA" (ByVal lpString As Long) As Long
Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (lpvDest As Any, lpvSource As Any, ByVal cbCopy As Long)
Private Sub Form_Load()
  Dim lngRet As Long, strDest As String, lLen As Long
  Dim strtemp As String
  Me.AutoRedraw = True

  'retrieve the initial pointer to the environment strings
  lngRet = GetEnvironmentStrings
  Do
    'get the length of the following string
    lLen = lstrlen(lngRet)
    'if the length equals 0, we've reached the end
    If lLen = 0 Then Exit Do
    'create a buffer string
    strDest = Space$(lLen)
    'copy the text from the environment block
    CopyMemory ByVal strDest, ByVal lngRet, lLen
    'show the text
    strtemp = strtemp & Replace(strDest, Chr(0), "") & vbCrLf
    'move the pointer
    lngRet = lngRet + lstrlen(lngRet) + 1
  Loop

  'clean up
  FreeEnvironmentStrings lngRet

  MsgBox strtemp
End Sub