Binaryworld - Use CopyMemory api for performance. ... [ VB -> Memory ]

This article will demonstrate that how CopyMemory can boost the performance of for some simple operations (e.g string append.). Here we will banchmark VB Mid function vs CopyMemory Api.

Click here to copy the following block

Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (pDst As Any, pSrc As Any, ByVal ByteLen As Long)
Private Declare Function GetTickCount Lib "kernel32" () As Long
Private Sub Form_Load()
  Dim sSave As String, Cnt As Long, T As Long, Pos As Long, Length As Long
  Const mStr = "Hello "
  Length = Len(mStr)
  sSave = Space(15000 * Length) 'make buffer for justified comparison
  'Get the current tickcount
  T = GetTickCount
  Pos = 1
  sSave = Space(15000 * Length) 'Create Buffer
  For Cnt = 1 To 15000
   'Copy string into buffer using vb Mid function
   Mid(sSave, Pos, Length) = mStr
   Pos = Pos + Length
  Next Cnt
  'Show the results
  MsgBox "It took Visual basic" + Str$(GetTickCount - T) + " msecs. to add 15000 times a string to itself."
  'Get the current tickcount
  T = GetTickCount
  Pos = 0
  sSave = Space(15000 * Length) 'Create Buffer
  For Cnt = 1 To 15000
    'Copy string into buffer using CopyMemory API
    CopyMemory ByVal StrPtr(sSave) + Pos, ByVal StrPtr(mStr), LenB(mStr)
    Pos = Pos + LenB(mStr)
  Next Cnt
  'see the difference in performance
  MsgBox "It took CopyMemory" + Str$(GetTickCount - T) + " msecs. to add 15000 times a string to itself."
End Sub